This software is subject to the "Standard Amiga FD-Software Copyright Note".
It is GIFTWARE/MAILWARE as defined in paragraph 4g/4b.
For more information please read "AFD-COPYRIGHT" (Version 1.4 or higher).

• two files: in this case the two files will be compared.
• a file and a directory: in this case the file will be compared with a equal called file in the directory. From now on, this will be the same like the comparison of two files, in contrast to the comparison of two directories.
• two directories or patterns: in this case all files (possibly matching the pattern) will be compared with equal called files in the 2nd directory and the other way round.

DUMP: Disk.info                   Test.info                   
0010: 00000002 00000A40 .......@  00000002 0000099B ........
0018: 00000CBF 00000106 ...¿....  000001B6 00000017 ...¶....
0020: 000003E9 00000A40 ...é...@  000003E9 0000099B ...é....
0028: 2C780004 2A4F226E ,x..*O"n  48E77EFE 24482400 Hç~þ$H$.
0030: 01144AA9 00AC6652 ..J©.¬fR  49F90000 00002C78 Iù....,x
0038: 41E9005C 2F084EAE Aé.\/.N®  000447F9 000005AC ..Gù...¬
Disk.info: Found 31 differences in contents&length until abort

/*
** Update only all neccesary files from dir A -> dir B
**                 ©1999/2000 ALeX Kazik
*/

/* IMPORTANT: the src/dst dir MUST end with a colon or slash and MUST NOT be empty! */

/* SOURCE directory */
src = 'a/'

/* DESTINATION directory */
dst = 'b/'

/* the script to create, and which will be executed */
script = 'T:script'

/* SKIP the first N bytes */
skip = 0

/* temporary file */
tmpfile = 'T:update.tmp'

/*
** The main-program
*/

ADDRESS COMMAND

cmp 'A="' || src || '" B="' || dst || '" all nostat norc skipfirstnbytes=' || SKIP ,
    || ' newdir=10 newfile revbdir detail lformat %r%R%n >"' || TMPFILE || '"'
IF RC >= 20 THEN DO
	SAY 'Error while executing cmp'
	EXIT RC
END

CALL OPEN(tmp, tmpfile, 'read')
CALL OPEN(scr, script, 'write')

eq = 0

DO UNTIL EOF(tmp)
  act = READCH(tmp, 1)
  file = READLN(tmp)
  IF act = '' THEN
    BREAK
  ELSE IF act = 'Q' THEN
    eq = eq + 1
  ELSE IF (act = 'A') | (act = '5') | (act = '9') THEN DO
    SAY 'File to remove: ' || file
    CALL WRITELN(scr, 'delete "' || dst || file || '" quiet')
  END
  ELSE IF (act = '4') | (act = '8') THEN DO
    SAY 'Dir to remove: ' || file
    CALL WRITELN(scr, 'delete "' || dst || file || '" quiet')
  END
  ELSE IF (act = 'B') | (act = '3') | (act = '7') THEN DO
    SAY 'New File: ' || file
    CALL WRITELN(scr, 'copy "' || src || file || '" "' || dst || file || '"')
  END
  ELSE IF (act = '2') | (act = '6') THEN DO
    SAY 'New Dir: ' || file
    CALL WRITELN(scr, 'makedir "' || dst || file || '"')
  END
  ELSE IF (act = 'E') | (act = '0') | (act = '1') THEN DO
    SAY 'Error/Warning at dir/file: ' || file
    EXIT 20
  END
  ELSE IF (act = 'L') | (act = 'C') | (act = 'D') | (act = 'S') | (act = 'T') THEN DO
    SAY 'File to Update: ' || file
    CALL WRITELN(scr, 'copy "' || src || file || '" "' || dst || file || '"')
  END
  ELSE DO
    SAY 'Unknown Symbol >' || act || '<'
    CALL CLOSE(tmp)
    CALL CLOSE(scr)
    EXIT 20
  END
END

SAY eq || ' Equal files.'

CALL CLOSE(tmp)
CALL CLOSE(scr)

/*
** executing the changes
*/

execute '"' || script || '"'

/*
** That's all.
*/